ARDUINO PASSION

Programme :​

/* Snootlab est un programme qui enregistre sur une carte SD la date, l'heure et la valeur de la température */
        

#include <Wire.h>                                                                            // appel des bibliothèques
#include <SD.h>
#include <RTClib.h>

#define chipSelect 10                                                                      // affectation des broches
#define capteur A0                               

// Declaration des variables générales
const unsigned long freq_rafraichissement = 5000;                   // entrez ici la fréquence de rafraichissement du capteur, en millisecondes
RTC_DS1307 RTC;                                                                           // création de l'objet RTC 
File fichier;
String datastring;

void setup()
{    
    Serial.begin(57600);                                                                    // initialisation de la liaison série
    Serial.print("Initialisation de la SD card...");
         
    pinMode(chipSelect, OUTPUT);                                                  // la broche chipSelect est en sortie
    Wire.begin();                        
    RTC.begin();                                                                                 // initialisation de l'objet RTC                 
          if (! RTC.isrunning())                                                             // si la RTC n'est pas configurée, le faire avec les valeurs de l'ordinateur au moment de la compilation
            {
            RTC.adjust(DateTime(__DATE__, __TIME__));
            }
         
          if (!SD.begin(chipSelect))                                                    // vérification de la présence de la carte SD 
            {                         
              Serial.println("Carte fausse ou absente");
              return;                                                                              // si problème, sortir et bloquer l'exécution
            }
          Serial.println("Carte OK.");
          datastring = "\nReleve et horodatage des valeurs du capteur, selon horloge RTC\n---------\n ";
          fichier = SD.open("data.txt", FILE_WRITE);                      // ouverture du fichier en mode Ecriture.
          if (fichier)                                                                            // si le fichier existe déja, on écrira à la suite des données présentes.
            {
              fichier.println(datastring);
              fichier.close();
              Serial.println(datastring);                                            // dupliquer la donnée sur port série
            }
          else                                                                                    // si problème à l'ouverture, alors signaler l'erreur
            {                                                       
              Serial.println("erreur d'ouverture du fichier durant la configuration");
            }
}

void loop()
{
   delay(freq_rafraichissement);
   DateTime moment = RTC.now();                                            // acquisition des données de l'horloge 
   datastring=String(moment.day(),DEC);
   datastring+='/';
   datastring+=String(moment.month(),DEC);
   datastring+='/';
   datastring+=String(moment.year(),DEC);
   datastring+=' ';
   datastring+=String(moment.hour(),DEC);
   datastring+=':';
   datastring+=String(moment.minute(),DEC);
   datastring+=':';
   datastring+=String(moment.second(),DEC);
          
   float sensor = analogRead(capteur);                                 // lire la valeur du capteur et la mettre dans la chaine de caractères
   float temp = sensor*500/1024;                                          // conversion de la valeur du capteur en degré celcius
          
   datastring += ("\t Valeur capteur = ");                               // préalablement remplie avec les données temporelles
   datastring += String(sensor);
   datastring += ("\t Valeur temperature = ");                      // préalablement remplie avec les données temporelles
   datastring += String(temp);
   fichier = SD.open("data.txt", FILE_WRITE);
          if (fichier)
            {
              fichier.println(datastring); 
              fichier.close(); 
              Serial.println(datastring);                                       // dupliquer la donnée sur port série
            }
          else 
            {
             Serial.println("erreur d'ouverture du fichier");
            }
   datastring ="0";
}